From fa080de7afc95aa1c19a6e6fc0e0708ced2eadc4 Mon Sep 17 00:00:00 2001
From: Joseph Hunkeler <jhunkeler@gmail.com>
Date: Wed, 8 Jul 2015 20:46:52 -0400
Subject: Initial commit

---
 noao/imred/ccdred/setinstrument.cl | 57 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 noao/imred/ccdred/setinstrument.cl

(limited to 'noao/imred/ccdred/setinstrument.cl')

diff --git a/noao/imred/ccdred/setinstrument.cl b/noao/imred/ccdred/setinstrument.cl
new file mode 100644
index 00000000..c10a7427
--- /dev/null
+++ b/noao/imred/ccdred/setinstrument.cl
@@ -0,0 +1,57 @@
+# SETINSTRUMENT -- Set up instrument parameters for the CCD reduction tasks.
+#
+# This task sets default parameters based on an instrument ID.
+
+procedure setinstrument (instrument)
+
+char	instrument		{prompt="Instrument ID (type ? for a list)"}
+char	site="kpno"		{prompt="Site ID"}
+char	directory="ccddb$"	{prompt="Instrument directory"}
+bool	review=yes		{prompt="Review instrument parameters?"}
+char	query			{prompt="Instrument ID (type q to quit)",
+				 mode="q"}
+
+begin
+	string	inst, instdir, instmen, instfile
+
+	# Define instrument directory, menu, and file
+	instdir = directory
+	if (site != "")
+	    instdir = instdir // site // "/"
+	instmen = instdir // "instruments.men"
+	inst = instrument
+	instfile = instdir // inst // ".dat"
+
+	# Loop until a valid instrument file is given.
+	while (inst != "" && !access (instfile)) {
+	    if (access (instmen))
+		page (instmen)
+	    else if (inst == "?")
+		print ("Instrument list ", instmen, " not found")
+	    else
+	        print ("Instrument file ", instfile, " not found")
+	    print ("")
+	    inst = query
+	    if (inst == "q")
+		return
+	    instrument = inst
+	    instfile = instdir // inst // ".dat"
+	}
+
+	# Set instrument parameter.
+	if (access (instfile))
+	    ccdred.instrument = instfile
+	else
+	    ccdred.instrument = ""
+
+	# Run instrument setup script.
+	instfile = instdir // inst // ".cl"
+	if (access (instfile))
+	    cl (< instfile)
+
+	# Review parameters if desired.
+	if (review) {
+	    eparam ("ccdred")
+	    eparam ("ccdproc")
+	}
+end
-- 
cgit