From fa080de7afc95aa1c19a6e6fc0e0708ced2eadc4 Mon Sep 17 00:00:00 2001
From: Joseph Hunkeler <jhunkeler@gmail.com>
Date: Wed, 8 Jul 2015 20:46:52 -0400
Subject: Initial commit

---
 sys/imfort/imgl2s.x | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 sys/imfort/imgl2s.x

(limited to 'sys/imfort/imgl2s.x')

diff --git a/sys/imfort/imgl2s.x b/sys/imfort/imgl2s.x
new file mode 100644
index 00000000..ea8596e1
--- /dev/null
+++ b/sys/imfort/imgl2s.x
@@ -0,0 +1,52 @@
+# Copyright(c) 1986 Association of Universities for Research in Astronomy Inc.
+
+include	<imhdr.h>
+include	"imfort.h"
+
+# IMGL2S -- Get a line from an image of type short.  It is illegal to reference
+# out of bounds.
+
+procedure imgl2s (im, buf, lineno, ier)
+
+pointer	im			# image descriptor
+short	buf[ARB]		# user data buffer
+int	lineno			# line number
+int	ier
+
+long	offset
+int	nchars, npix
+int	bfread()
+
+begin
+	# Verify in bounds.
+	if (lineno < 1 || lineno > IM_LEN(im,2)) {
+	    ier = IE_YOOB
+	    call im_seterrim (ier, im)
+	    return
+	}
+
+	# Verify that the image is of type short.
+	if (IM_PIXTYPE(im) != TY_SHORT) {
+	    ier = IE_NOTSHORT
+	    call im_seterrim (ier, im)
+	    return
+	}
+
+	npix = IM_LEN(im,1)
+	nchars = npix * IM_SZPIXEL(im)
+
+	# Compute offset into pixel file.
+	offset = IM_PIXOFF(im) + (lineno-1) * IM_LINESIZE(im)
+
+	# Read one line of data.
+	if (nchars != bfread (IM_PIXFP(im), buf, nchars, offset)) {
+	    ier = IE_RDPIX
+	    call im_seterrim (ier, im)
+	    return
+	}
+
+	# Swap bytes if necessary.
+	call imswap (im, buf, nchars)
+
+	ier = OK
+end
-- 
cgit