# $Id$
# Maintainer: Pierre Schmitz <pierre@archlinux.de>

pkgname=openssl
_ver=1.1.0g
# use a pacman compatible version scheme
pkgver=${_ver/[a-z]/.${_ver//[0-9.]/}}
#pkgver=$_ver
pkgrel=1
pkgdesc='The Open Source toolkit for Secure Sockets Layer and Transport Layer Security'
arch=('x86_64')
url='https://www.openssl.org'
license=('custom:BSD')
#depends=('perl') #TODO
optdepends=('ca-certificates')
backup=('etc/ssl/openssl.cnf')
source=("https://www.openssl.org/source/${pkgname}-${_ver}.tar.gz"
        "https://www.openssl.org/source/${pkgname}-${_ver}.tar.gz.asc")
        #'ca-dir.patch')
sha256sums=('de4d501267da39310905cb6dc8c6121f7a2cad45a7707f76df828fe1b85073af'
            'SKIP')
            #'90c7411fed0157116f2df8f4be755aaf5a26e8484351b4e6a79492805d5f2790')
validpgpkeys=('8657ABB260F056B1E5190839D9C4D26D0E604491')

prepare() {
        cd "$srcdir/$pkgname-$_ver"

        # set ca dir to /etc/ssl by default
        #patch -p0 -i "$srcdir/ca-dir.patch"
}

build() {
        cd "$srcdir/$pkgname-$_ver"

        if [[ $(uname -s) == Linux ]]; then
            if [ "${CARCH}" == 'x86_64' ]; then
                openssltarget='linux-x86_64'
                optflags='enable-ec_nistp_64_gcc_128'
            elif [ "${CARCH}" == 'i686' ]; then
                openssltarget='linux-elf'
                optflags=''
            fi
        elif [[ $(uname -s) == Darwin ]]; then
            openssltarget='darwin64-x86_64-cc'
            optflags='enable-ec_nistp_64_gcc_128'
        fi

        # mark stack as non-executable: http://bugs.archlinux.org/task/12434
        ./Configure --prefix=$BUILD_PREFIX \
            --openssldir=$BUILD_PREFIX/etc/ssl \
            --libdir=lib \
            shared \
            no-ssl3-method \
            ${optflags} \
            "${openssltarget}" \
            "-Wa,--noexecstack ${CPPFLAGS} ${CFLAGS} ${LDFLAGS}"

        make depend
        make
}

check() {
        cd "$srcdir/$pkgname-$_ver"
        # the test fails due to missing write permissions in /etc/ssl
        # revert this patch for make test
        #patch -p0 -R -i "$srcdir/ca-dir.patch"
        make test
        #patch -p0 -i "$srcdir/ca-dir.patch"
}

package() {
        cd "$srcdir/$pkgname-$_ver"
        make DESTDIR=$pkgdir MANDIR=${BUILD_PREFIX}/share/man MANSUFFIX=ssl install_sw install_ssldirs install_man_docs
        fix_rpath
        install -D -m644 LICENSE $pkgdir${BUILD_PREFIX}/usr/share/licenses/$pkgname/LICENSE
}