1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
SUBROUTINE sla_V2TP (V, V0, XI, ETA, J)
*+
* - - - - -
* V 2 T P
* - - - - -
*
* Given the direction cosines of a star and of the tangent point,
* determine the star's tangent-plane coordinates.
*
* (single precision)
*
* Given:
* V r(3) direction cosines of star
* V0 r(3) direction cosines of tangent point
*
* Returned:
* XI,ETA r tangent plane coordinates of star
* J i status: 0 = OK
* 1 = error, star too far from axis
* 2 = error, antistar on tangent plane
* 3 = error, antistar too far from axis
*
* Notes:
*
* 1 If vector V0 is not of unit length, or if vector V is of zero
* length, the results will be wrong.
*
* 2 If V0 points at a pole, the returned XI,ETA will be based on the
* arbitrary assumption that the RA of the tangent point is zero.
*
* 3 This routine is the Cartesian equivalent of the routine sla_S2TP.
*
* P.T.Wallace Starlink 27 November 1996
*
* Copyright (C) 1996 Rutherford Appleton Laboratory
*-
IMPLICIT NONE
REAL V(3),V0(3),XI,ETA
INTEGER J
REAL X,Y,Z,X0,Y0,Z0,R2,R,W,D
REAL TINY
PARAMETER (TINY=1E-6)
X=V(1)
Y=V(2)
Z=V(3)
X0=V0(1)
Y0=V0(2)
Z0=V0(3)
R2=X0*X0+Y0*Y0
R=SQRT(R2)
IF (R.EQ.0.0) THEN
R=1E-20
X0=R
END IF
W=X*X0+Y*Y0
D=W+Z*Z0
IF (D.GT.TINY) THEN
J=0
ELSE IF (D.GE.0.0) THEN
J=1
D=TINY
ELSE IF (D.GT.-TINY) THEN
J=2
D=-TINY
ELSE
J=3
END IF
D=D*R
XI=(Y*X0-X*Y0)/D
ETA=(Z*R2-Z0*W)/D
END
|
