1 files changed, 48 insertions, 0 deletions
diff --git a/pkg/images/imutil/src/imamax.gx b/pkg/images/imutil/src/imamax.gx
new file mode 100644
index 00000000..5804825f
--- /dev/null
+++ b/pkg/images/imutil/src/imamax.gx
@@ -0,0 +1,48 @@
+# Copyright(c) 1986 Association of Universities for Research in Astronomy Inc.
+
+include	<imhdr.h>
+
+# IMA_MAX -- Image arithmetic maximum value.
+
+$for (silrd)
+procedure ima_max$t (im_a, im_b, im_c, a, b)
+
+pointer	im_a, im_b, im_c
+PIXEL	a, b
+
+int	len
+pointer	im[3], buf[3]
+long	v[IM_MAXDIM, 3]
+
+int	ima_nl$t()
+
+begin
+	# Loop through all of the image lines.
+	im[1] = im_c
+	len = IM_LEN (im[1], 1)
+	call amovkl (long(1), v, 3 * IM_MAXDIM)
+
+	# If imagea is constant then read imageb and do the vector/scalar
+	# maximum to imagec.
+	if (im_a == NULL) {
+	    im[2] = im_b
+	    while (ima_nl$t (im, buf, v, 2) != EOF)
+		call amaxk$t (Mem$t[buf[2]], a, Mem$t[buf[1]], len)
+
+	# If imageb is constant then read imagea and do the vector/scalar
+	# maximum to imagec.
+	} else if (im_b == NULL) {
+	    im[2] = im_a
+	    while (ima_nl$t (im, buf, v, 2) != EOF)
+		call amaxk$t (Mem$t[buf[2]], b, Mem$t[buf[1]], len)
+
+	# Read imagea and imageb and do a vector-vector maximum
+	# operation to imagec.
+	} else {
+	    im[2] = im_a
+	    im[3] = im_b
+	    while (ima_nl$t (im, buf, v, 3) != EOF)
+		call amax$t (Mem$t[buf[2]], Mem$t[buf[3]], Mem$t[buf[1]], len)
+	}
+end
+$endfor